【VBA】Findメソッドの基本的な使い方（引数の使い方、戻り値、注意点と代替手段）

こんにちは、hokkyokunです。

もともとVBAに備わっているメソッドなので
すぐ使え、書籍にも「セルを検索する手法」として多く取り扱われています。

一方、ちょっと使い方に癖があり、難しめのメソッドでもあります。
使い方を確認していきましょう。

タイトルに「基本的」と入れましたが、
かなりマニアックなところまで含めて書きました。
この記事を読めばFindメソッドのことがかなりわかると思います。

Findメソッドの記事をいくつかかいています。
よかったら他の記事も見ていってください。

Findメソッドの基本構文

構文

基本構文は以下のようになります。

Dim Rng As Range

Rng.Find(what:="検索する値", _
        After:="セルを指定。このセルより後から検索", _
        LookIn:="xlValues:値 or xlFormula:計算式 or xlComments:コメント", _
        LookAt:="xlWhole:完全一致 or xlPart:部分一致", _
        SearchOrder:="xlByRows:横方向 or xlByColumns:縦方向", _
        SearchDirection:="xlNext:順方向 or xlPrevious:逆方向", _
        MatchCase:="True:大文字小文字区別する or False:区別しない", _
        MacthByte:="True:半角全角区別する or False:区別しない", _
        SearchFormat:="True:書式設定検索する or False:しない")

引数

引数の内容説明です。

たくさんありますね、
ただほとんど不要です。

詳しい使い方は下記の「使い方」で
引数別に紹介します。

×はむしろ使うべきではありません。

検索する位置や方向を指定していますが、
ここをいじって検索結果をどうこうするよりかは
エクセルの表の作り方やプログラミングコードを見直すべきです。

引数を省略するとどうなる？

Findメソッドを極端に難しくしている謎の仕様がこれなのですが、
引数によって省略した場合の対応が異なります。

頭が痛くなりそうですが
ポイントは二つです。

詳しくは本ページ下記の「注意点」を見てください。

控えめに言っても大混乱させる仕様です(笑)

Findメソッドよりも簡単で高速、エラーも起こしにくい関数を作ったので
よかったら見て頂ければと思います。

【VBA】Findメソッドよりも簡単、早い！高速でセル位置を検索、取得する方法。完全一致、部分一致対応。複数セル取得対応。 わかること Findメソッドよりも高速で操作が簡単、エラーにも強い方法を紹介します。 オリジナル関数ですが、コピペで使えます。...

こちらはFindNextメソッドの代替手段（関数）です。

【VBA】FindNextメソッドうまくいかないなら試してみて！セル範囲を全検索する方法（簡単、高速、エラーにも強い） このページでわかること 指定したセル範囲のうち、特定のセルを全取得する方法がわかります。 オリジナル関数です。3つの関数をコピ...

戻り値

戻り値はレンジオブジェクトです。
つまりセルを返してくれます。

あるあるなのが
セルが返ってくると思って「.Value」で値を参照して
エラーが吐き出されるという現象です。

しっかりエラー対策をしておきましょう。

こちらに記事がありますので参考にしてみてください

【VBA Findメソッド】あるのに見つからない場合に試すこと４選。エラー回避と代替手段 このページでわかること Findメソッドは見つからない場合、続けて処理するとエラーが生じる可能性がある。→エラー回避方法を紹介 ...

Findメソッドとエクセルのダイアログ検索ボックス(Ctrl + F)

複雑な構造のFindメソッドですが、
これはエクセル上で「Ctrl + F 」で開く検索ダイアログと同じ構造になっています。

比較してみましょう。

こうやってみるとダイアログボックスのほとんどの仕様を
VBAで動かせるようです。

引数別の使い方

下記の図のような表を用意します。
セル範囲 A1:C6 を引数を変えながら検索してみようと思います。

下記でも述べていますが、
Findメソッドには注意する点が三つあります。

詳しくは下記に記載している「注意点」を確認してください。

What：検索する値を指定

まずはWhatの使い方と
他の引数を指定しない場合（＝デフォルト）での検索の仕方を確認しておこうと思います。

Sub test1()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1")

Debug.Print ws.Range("A1:C6").Find(what:="リンゴ").Address
'>>$C$1

ws.Range("A1:C6").Find(what:="リンゴ").Borders.Color = vbRed

End Sub

デフォルトでは行方向（横方向）への検索となるので
C1が最初にヒットします。
A2ではないことを注意しましょう。

※Whatの内容とは関係ないのですが、
上記のコードを試した後ダイアログボックスを確認してみると
「半角全角の区別をする」にチェックが入っています。

引数を指定しないとデフォルトで
半角全角の区別をするになります。

また、その仕様は引き継がれます。

注意が必要です
というかなんだこの仕様…

After：検索開始位置を指定

Afterで検索開始位置を変更します。
A2を指定した場合の動きを確認しましょう。

Sub test2()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1")

Debug.Print ws.Range("A1:C6").Find(what:="リンゴ", After:=ws.Range("A2")).Address
'>>$A$6

ws.Range("A1:C6").Find(what:="リンゴ", After:=ws.Range("A2")).Borders.Color = vbRed
End Sub

今回でいうとA6がヒットします。

A2ではないことに注意しましょう。
Findメソッドは指定したセルの次のセルから検索を開始する仕様となっています。

LookIn：検索対象を指定

LookInは何を対象として検索するかを指定できます。

コメントの内容を検索してみましょう。

Sub test3()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="リンゴ", LookIn:=xlComments).Address
'>>$A$4

ws.Range("A1:C6").Find(what:="リンゴ", LookIn:=xlComments).Borders.Color = vbRed
End Sub

コメント検索ですので、
A4がヒットします。

C1やA2ではないですね。

LookAt：完全一致か部分一致か

かなりお世話になる引数です。
完全一致させるか部分的にでも一致しているかは実務において非常に重要です。

「リン」を完全一致させましょう。

Sub test4()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="リン", LookAt:=xlWhole).Address
'>>$C$2

ws.Range("A1:C6").Find(what:="リン", LookAt:=xlWhole).Borders.Color = vbRed

End Sub

「リン」を部分一致させたら、C1がヒットしますが、
完全一致にしたのでC2がヒットしました。

最も重要な引数と言えるかもしれません。

SearchOrder：検索方向を行方向か列方向か指定

Sub test5()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="リンゴ", searchorder:=xlByColumns).Address
'>>$A$2

ws.Range("A1:C6").Find(what:="リンゴ", searchorder:=xlByColumns).Borders.Color = vbRed
End Sub

C1ではなく、A2がヒットしました

SearchDirection：順方向か逆方向か

通常は左から右、上から下への検索をかけていきますが、
逆方向から検索をかけることも可能です。

Sub test6()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="リンゴ", SearchDirection:=xlPrevious).Address
'>>$A$6

ws.Range("A1:C6").Find(what:="リンゴ", SearchDirection:=xlPrevious).Borders.Color = vbRed
End Sub

C1ではなくA6がヒットしました。

MatchCase：大文字小文字を区別する、しない

大文字小文字を区別する場合ももしかしたらあるかもしれません
「apple」ではなく「Apple」を検索してみましょう。

Sub test7()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="Apple", MatchCase:=True).Address
'>>$A$5

ws.Range("A1:C6").Find(what:="Apple", MatchCase:=True).Borders.Color = vbRed
End Sub

A4の「apple」を通り過ぎて
A5の「Apple」をヒットさせました。

MatchByte：半角全角を区別する、しない

半角「ﾘﾝ」をヒットさせてみます。
「リンゴ」などは無視させて、「リン」と「ﾘﾝ」の比較対象を行うため
完全一致で検索します。

Sub test8()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

Debug.Print ws.Range("A1:C6").Find(what:="ﾘﾝ", LookAt:=xlWhole, MatchByte:=True).Address
'>>$A$3
ws.Range("A1:C6").Find(what:="ﾘﾝ", LookAt:=xlWhole, MatchByte:=True).Borders.Color = vbRed


'半角全角の区別をつけないとC2がヒットする
Debug.Print ws.Range("A1:C6").Find(what:="ﾘﾝ", LookAt:=xlWhole, MatchByte:=False).Address
'>>$C$2

End Sub

ちなみにですが、
「ﾘﾝｺﾞ」ではうまくいきません。

MatchByteの引数をTrueにしようがFalseにしようが
What:=ﾘﾝｺﾞでは「リンゴ」はヒットしません。
いずれにしても「ﾘﾝｺﾞ」だけヒットします。

「ﾘﾝｺﾞ」の「゛」が原因だと思いますが、
あまり深追いしても使い道がないので検証はこのあたりにしておきます。

SearchFormat：検索する書式を指定する、しない

こちらに関しては内容が多岐にわたるので
別記事でご紹介します。

Findメソッドの注意点

ちょこちょこ申し上げましたが、
改めてFindメソッドの注意点をまとめてみます。

検索セル範囲の先頭は最後に検索される

例えば、下図のような表で
A1:C6の範囲で「リンゴ」を検索するとします。

Sub test_range()

Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(2)

Debug.Print ws.Range("A1:C6").Find("リンゴ").Address
'>>$C$1
End Sub

素直に考えればA1セルを取得できると思いますが、
実際にはC1セルです。

MatchByteの引数は要注意

MatchByteは半角全角を区別するかどうかの引数です。

エクセルを開いて最初にFindメソッドを使う場合、
引数を指定しないと勝手にTrueとして半角全角を区別します。

しかもその後は、前回の設定に依存するので
次回以降も区別し続けます。

引数の設定が前回の処理に引っ張られる

上記でもまとめた表と同じですが、
特に前回の処理に引っ張られるものを赤字で協調しておきます。

使用状況により直ちに影響があるかどうかはケースバイケースですが、
挙動を安定させるためには少なくとも

どちらかの対策を行うことをお勧めします。

私がよく使うデフォルトに戻すためのコードです。
これをプロシージャの最後に組んで、適切に引数を管理していただければと思います。

Dim Rng As Range
Set Rng = Range("A1").Find(what:="", _
            LookIn:=xlValues, _
            LookAt:=xlPart, _
            MatchByte:=False, _
            SearchOrder:=xlRows)

※正確にはLookInはFormula（数式）がデフォルト値ですが、
使い勝手が良いのはValues（値）なのでそうしています。
Formulaの方が都合が良ければお手数ですが少し変更してお使いください。

※変数を「Rng」としていますが、
もちろんなんでも大丈夫です。
プログラムに合わせて修正してください。

Findメソッドの代わりになる方法

いかがでしょうか

VBAで何かを検索する際にはついついFindメソッドを頼りがちですが
結構めんどくさい仕様があったりもします。

ちなみに、私はVBAで開発するとき
Findメソッドはほぼ使いません。

For文を駆使して該当のセルを見つけるか
以下のオリジナル関数を使って対処しています。

とはいえ、FindメソッドにはFindメソッドの良さもあります。

ちょっとしたプログラムであれば
For文を書いたり、上記の関数をコピペしたりせずに
Findメソッドを使って書いてもいいと思います。

何はともあれ、自分の引き出し（＝使える手段）は
多ければ多いほど良いです。

まとめ

VBAの学習方法をまとめました。

VBA（マクロ）のおすすめの学習方法 こんにちはhokkyokunです。 VBAを学ぶことで確実に業務は効率化し、余裕をもって仕事をすることができるようになります。 ...

VBAを高コスパで、短期間で学ぶにはUdemyがおすすめです。
Udemyは良質の学習プラットフォームですが、
動画数が多すぎてどれを見ればよいか迷います。

おすすめの講師をまとめました。

【Udemyは講師で選べ！】UdemyがVBA学習に最適な理由とおすすめのVBA講師 こんにちはhokkyokunです。 巨大学習プラットホームUdemyの中からVBAに関する動画について講師に焦点を当ててまとめま...

Findメソッドの他の記事です。

ブログ村ランキング参加中です。よかったらフォローお願いします！！